;;;
;;; a first attempt at mapping (systematically) between the grammar-internal
;;; name space (where, for example, there may be reasons to group sets of index
;;; properties in nested feature structures) and the external, SEM-I compliant
;;; interface.
;;;

;;;
;;; the correspondence between grammar-internal types and the one-letter codes
;;; encoding value types on MRS variables: the type mapping, conceptually, is
;;; applied parallel to the property mapping, i.e. context conditions in rules
;;; below should be cast in the appropriate name space.
;;;
event          <> e
ref-ind        <> x
individual     <> i
handle         <> h
non_event      <> p
*              >> u
semarg         << u


;;;
;;; from here on, sets of rules that map one or more properties into one or
;;; more properties: for each correspondence, values are compared to sub-rules
;;; in order, until the first match: at that point, output values are inserted
;;; into the result set of properties.  processing of rules continues against
;;; the original properties, so that there could be multiple matches: the `PN'
;;; to `PERS' and `NUM' decomposition, thus, could also be done in two separate
;;; rule sets.  at the end of the day, however, only properties resulting from
;;; successful matches will be in the output, i.e. everything not explicitly
;;; carried over will be deleted.
;;;

PNG.PN : PERS NUM
  1s <> 1 sg
  1p <> 1 pl
  1  <> 1 !
  1  << 1 *
  2s <> 2 sg
  2p <> 2 pl
  2  <> 2 !
  2  << 2 *
  3s <> 3 sg
  3p <> 3 pl
  3  <> 3 !
  3  << 3 *
  *    >> ! !
  !    << * *


PNG.GEN : GEND
  masc    <> m
  fem     <> f
  neut    <> n
  animate <> m-or-f
  *       >> !
  !       << *


;;
;; the lexical property of being individuated, e.g. `road' _and_ `roads' will
;; both be [ IND + ], in contrast to DIV which co-varies with number.  to get
;; us started, this property projects the count vs. mass distinction into the
;; semantics, and dan at least argues that it is truly a semantic distinction.
;; so it might turn out that IND eventually replaces DIV in the interface.
;;                                                             (20-dec-06; oe)
;;
IND : IND
  + <> +
  - <> -
  * >> !
  ! << *


PRONTYPE : PRONTYPE
  std_pron  <> std_pron
  zero_pron <> zero_pron
  refl      <> refl
  *         >> !
  !         << *


SF : SF
  comm         <> comm
  ques         <> ques
  prop         <> prop
  prop-or-ques <> prop-or-ques
  basic-prop   >> prop
  basic-ques   >> ques
  basic-comm   >> comm
  prop-or-like >> prop
  *            >> prop
  prop         << *
  prop         << [e]


E.TENSE : TENSE
  nonpresent <> past
  present    <> pres
  future     <> fut
  real_tense <> tensed
  untensed   <> untensed
  *          >> untensed
  untensed   << *
  untensed   << [e]


E.MOOD : MOOD 
  indicative      <> indicative
  subjunctive     <> subjunctive
  *               >> indicative
  indicative      << *
  indicative      << [e]

E.ASPECT.PROGR : PROG
  +       <> +
  -       <> -
  *       >> -
  -       << *
  -       << [e]

E.ASPECT.PRF : PERF
  +       <> +
  -       <> -
  *       >> -
  -       << *
  -       << [e]